| To install to HD:
| 1. Create a !Minotaur directory on the HD
| 2. Copy everything except !boot into !Minotaur
| 3. Save this file as !Minotaur.!Run
IF "<Obey$Dir>"="@" THEN Set Obey$Dir ADFS::0.$
StoreCSD
DIR <Obey$Dir>
HideCommandWindow
IF ADFFS$OSVersion>=&50000 THEN ADFRemapVideoMemory 13 160 ELSE ScreenSize 40
| Allow Mouse cursor to update at 50Hz
IF ADFFS$OSVersion>=&50000 THEN ADFForceVSync 2
SpriteFree 40
WimpSlot -min 512k -max 512k
Set Alias$SCHO. SChoose %%*0
Set Alias$K. KEY<32>
LOAD BANNER 9000
ADFCRC 9000 9317 2CFFB959 BANNER 
| Replace 340 CHAIN"MINOM" with END, so we can patch MINOM
MEMA B 9091 E0 3A
BASIC -quit @00009000,00009318
| Slow down turning left
SET Key$0 1990FORA%=0TO32:WAIT:VDU23,7,0,0||:NEXT|M
| Slow down turning right
SET Key$0 <Key$0>2090FORA%=0TO32:WAIT:VDU23,7,0,1,0||:NEXT|M
| Slow down the maze calculation
SET Key$0 <Key$0>5795IFA%=1 WAIT|M5855IFA%=1 WAIT|M6265IFA%=1 WAIT|M
| Add delay to map
SET Key$0 <Key$0>2780PROCwindow:REPEAT:PROCdecrement:MOUSEA%,B%,C%:UNTILC%=0:ENDPROC|M
| Regulate game speed
SET Key$1 335W%=TIME|M375WHILE TIME<W%+4:WAIT:ENDWHILE|M
SET Key$1 <Key$1>325K%=TIME|M2610DEFPROCdecrement:IF(TIME-K%)<20:ENDPROC|M2660K%=TIME:ENDPROC|M
| Slow Minotaur animation
SET Key$1 <Key$1>3535L%=scr%:scr%=((TIME DIV16)AND 1)+1|M3600PLOT&8D,0,0:GCOL0,0:IFI%>2:scr%=L%:ENDPROC|M3645scr%=L%|M
| Slow runlikehell
SET Key$2 4885W%=TIME|M4905WHILE TIME<W%+20:WAIT:ENDWHILE|M
SET Key$2 <Key$2>*unset key$*|MRUN|F|M
ECHO <21>
FX 225,1
FX 21,0
FX 138,0,128
FX 138,0,129
FX 138,0,130
BASIC -load MINOM
IF ADFFS$OSVersion>=&50000 THEN ADFRemapVideoMemory
IF ADFFS$OSVersion>=&50000 THEN ADFForceVSync 0
Unset Alias$SCHO.
Unset Alias$K.
RestoreCSD